Interacting with Java

Since ByteSkript runs directly in the Java Virtual Machine (rather than interpreting scripts) all resources from the Java Development Kit and other third-party libraries are available when scripts are running.
One of the major design goals for ByteSkript's language implementation was to allow advanced users to interact with Java libraries directly, rather than needing pre-created syntax for this.
This is an advanced feature.
Calling Java Methods
There are two ways to call a Java method: either through the external function syntax or through a handle from the Skript function library.
For this tutorial we will be using the external function syntax.
1
run function_name(args...) from org/example/Class
2
run methodName() from org/example/Class
3
set {var} to nanoTime() from java/lang/System
Copied!
Java has two (main) types of method, which we will need to access slightly differently.
Calling Static Methods
To call a static method (which will look like public static Thing myMethod(Params..) in the Java library) we just need its class path.
To call System.nanoTime() we would need the System class's path (java.lang.System) and the method name (nanoTime).
We can then call it as we would an external Skript function from a different script file.
1
set {var} to nanoTime() from java/lang/System // calls our method
Copied!
This is identical to using a Skript function because scripts are compiled to classes before being run.
If we needed to pass arguments to the Java method, they can be entered as normal.
Arguments can be written directly or passed in variables, expressions, etc.
1
run myMethod("hello", 6) from my/java/Class
2
set {word} to "hello"
3
set {number} to 6
4
run myMethod({word}, {number}) from my/java/Class
Copied!
Unlike other JVM languages, ByteSkript does not need to know the parameter/argument types to run the method.
You can also pass arguments in atomic variables without an issue - these will be automatically unpacked where necessary.
1
set {@word} to "hello"
2
set {@number} to 6
3
run myMethod({@word}, {@number}) from my/java/Class
Copied!
Calling Dynamic Methods
The majority of Java libraries will use objects, and to interact with them you will be required to call dynamic (non-static) methods.
These belong to a particular object, rather than the class itself. Their behaviour can change between objects.
These are called with similar syntax, but we use the target object rather than its class.
This is the same syntax that is used for calling member functions from a custom type.
1
run setName("Bob") from {person}
2
run println("hello!") from {output}
3
run run() from {runnable}
4
set {var} to get() from {supplier}
Copied!
Creating and Using Classes
This section is designed for very advanced users.
Many libraries written in Java and other JVM languages will require extending, implementing or creating classes.
ByteSkript types are equivalent (and compile) to Java classes. Template types are equivalent (and compile) to Java interfaces.
Using Existing Java Interfaces
If a library requires you to implement an interface, you can use this interface as a template for your custom type.
In the example below, the java.util.function.Supplier<?> interface is being implemented, and the T get() method is being overridden.
1
type Getter:
2
    template: java/util/function/Supplier // we need the full path to it here
3
    function get:
4
        trigger:
5
            return "hello"
Copied!
We can now make one with a new Getter and use its functions.
1
type Getter:
2
    template: java/util/function/Supplier // we need the full path to it here
3
    function get:
4
        trigger:
5
            return "hello"
6
​
7
function test:
8
    trigger:
9
        set {getter} to a new Getter
10
        assert {getter} is a Getter // it's our custom type
11
        assert {getter} is a java/util/function/Supplier
12
        // it's also that Java type
13
        print get() from {getter} // runs the get() function
Copied!
Overriding Java Methods
This section is designed for very advanced users.
When using a Java library you may be required to override a specific method. This will require matching the correct parameter and return types.
These will go inside the custom type that extends or uses the Java class as a template. Some examples are given below.
Void Return Types
Java
Skript
1
public void myMethod(String string);
Copied!
1
function myMethod (string):
2
    parameters: String
3
    return: none
4
    trigger:
5
        print {string}
Copied!
Multiple Parameters
Java
Skript
1
public String myMethod(String a, Object b);
Copied!
1
function myMethod (string, object):
2
    parameters: string // the second parameter is already an Object
3
    return: string
4
    trigger:
5
        return {string} + " " + {object}
Copied!
There is no way to specify primitive parameters.

Tutorials - Previous

Contributing to ByteSkript

Next - Tutorials

Creating Custom Syntax

Last modified 2mo ago

Copy link

Contents

Calling Java Methods

Creating and Using Classes

Using Existing Java Interfaces

Overriding Java Methods